A Coluna de Fórmula é uma das maneiras mais populares de manipular dados na monday.com. Desde cálculos matemáticos simples até fórmulas mais complicadas, utilizando nossa biblioteca de funções disponíveis, a Coluna de Fórmula pode ajudar a simplificar problemas complexos.
Antes de mergulharmos neste artigo, no quadro abaixo, você encontrará alguns dos casos de uso mais comuns para a coluna Fórmula:
Sinta-se à vontade para simplesmente copiar e colar a fórmula fornecida na coluna ‘Fórmula’ diretamente no seu próprio quadro para uso!
Agora, vamos explorar mais alguns dos casos de uso que foram coletados. Abaixo você encontrará algumas das maneiras mais comuns de usar a Coluna de Fórmula ⬇️
Adicionando ou subtraindo dias de uma data
Neste exemplo, queremos adicionar 15 dias a cada data da coluna “Data de Início”:
ADD_DAYS({Data de Início},15)
Se quisermos subtrair 15 dias em vez disso, usaríamos a função SUBTRACT_DAYS() no lugar de ADD_DAYS().
SUBTRACT_DAYS({Data de Início},15)
Ambas as fórmulas acima mostrarão um resultado não formatado que pode parecer um pouco desajeitado. É por isso que recomendamos usar a seguinte fórmula. O resultado é formatado e parecerá mais limpo no seu quadro:
FORMAT_DATE(ADD_DAYS({Data de Início},15))
Se você quiser remover o ano e simplesmente ver o mês e o dia, pode personalizar ainda mais sua fórmula usando a função LEFT(). Na fórmula a seguir, a função LEFT() pega a saída da função FORMAT_DATE() e exibe apenas 6 caracteres da esquerda:
LEFT(FORMAT_DATE(ADD_DAYS({Data de Início},15)),6)
Se mudarmos o 6 na fórmula, mudamos o número de caracteres que a fórmula exibe. Os resultados dessa fórmula podem ser vistos na coluna “LEFT”:
Calculando dias entre uma data e hoje
Uma função realmente útil e dinâmica é a TODAY(). Usando isso com a função DAYS(), você pode calcular o número de dias até a data de vencimento (ou além da data de vencimento). Ao usar a TODAY(), você não precisa incluir nada dentro dos parênteses.
Também encapsulamos a saída da função DAYS() dentro da função ROUND(). Neste caso, estamos indicando que queremos arredondar a saída para 0 casas decimais.
ROUND(DAYS({Data de Vencimento},TODAY()),0)
Determinando o número de dias úteis entre duas datas
Se você estiver usando um quadro para rastrear solicitações de férias de funcionários, uma fórmula pode ser útil para calcular o número de dias úteis que o funcionário precisará. A função WORKDAYS() retornará o número de dias úteis entre duas datas. Dias úteis são definidos, de acordo com as configurações da sua conta, como segunda a sexta-feira ou domingo a quinta-feira. Para saber mais sobre essa configuração de conta, confira este artigo.
WORKDAYS({Para},{De})
Calculando o total faturável usando a coluna de rastreamento de tempo
Ao usar a Coluna de Rastreamento de Tempo com a Coluna de Fórmula, você pode escolher se deseja puxar segundos, minutos ou horas. Para a fórmula a seguir, estamos usando as horas da coluna “Faturável”. Também estamos usando a função ROUND() novamente para limpar nossos decimais. O número 2 nesta fórmula significa duas casas decimais.
ROUND(MULTIPLY({Faturável#Horas},{Taxa Horária}),2)
Totalizando horas trabalhadas excluindo intervalos
Neste exemplo, gostaria de calcular quanto tempo meus contratados trabalharam. Isso não deve incluir o tempo de intervalo não remunerado. Usando quatro Colunas de Hora, posso criar uma fórmula para calcular isso.
IF(HOURS_DIFF({Fim do Intervalo}, {Início do Intervalo}) > "0", HOURS_DIFF(HOURS_DIFF({Fim}, {Início}), HOURS_DIFF({Fim do Intervalo}, {Início do Intervalo})), HOURS_DIFF({Fim}, {Início}))
Essa fórmula diz que se o intervalo for maior que 0, calcule o total de horas trabalhadas menos o intervalo. Se o intervalo não for maior que 0, calcule o total de horas trabalhadas.
Veja como a fórmula funciona:
Calculando a mudança entre dois valores
Neste quadro, estamos analisando as vendas totais por mês de quatro funcionários. Para calcular a mudança entre os resultados de janeiro e fevereiro como uma porcentagem, você usaria a seguinte fórmula:
MULTIPLY(DIVIDE(MINUS({Vendas de Fevereiro},{Vendas de Janeiro}),{Vendas de Janeiro}),100)
Essa fórmula também pode ser escrita como:
((({Vendas de Fevereiro}-{Vendas de Janeiro})/{Vendas de Janeiro})*100)
Saída de um valor com base em duas condições
Agora queremos calcular o bônus de cada funcionário. Um funcionário receberá um bônus apenas se as “Vendas Totais” forem superiores a $350.000 e se o número de negócios na coluna “Negócios” for superior a 12:
IF(AND({Vendas Totais}>350000,{Negócios}>12),250,0)
A função AND() verifica se as duas condições são verdadeiras. Com base no resultado, a declaração IF() informa à coluna de fórmula qual valor retornar.
Usando rótulos de status para atribuir taxas de comissão
Neste exemplo, digamos que eu gerencio uma equipe de vendas com taxas de comissão variadas por vendedor. Você pode usar os rótulos da coluna de status para indicar uma taxa específica dentro da sua fórmula:
IF({Taxa}="Taxa 1",25,IF({Taxa}="Taxa 2",20,IF({Taxa}="Taxa 3",15,IF({Taxa}="Taxa 4",10,IF({Taxa}="Taxa 5",5)))))
A coluna “Comissão %” exibe a taxa relevante com base no rótulo de status selecionado.
Você pode levar essa fórmula um passo adiante calculando a comissão com base na taxa e na coluna “Vendas Totais”, usando a função MULTIPLY(). Apenas tenha em mente que se você usar um decimal em uma fórmula, deve escrever 0.25 em vez de .25 para evitar um erro de fórmula ilegal.
IF({Taxa}="Taxa 1",MULTIPLY(0.25,{Vendas Totais}),IF({Taxa}="Taxa 2",MULTIPLY(0.20,{Vendas Totais}),IF({Taxa}="Taxa 3",MULTIPLY(0.15,{Vendas Totais}),IF({Taxa}="Taxa 4",MULTIPLY(0.10,{Vendas Totais}),IF({Taxa}="Taxa 5",MULTIPLY(0.05,{Vendas Totais}))))))
Comparando um valor dinâmico a um valor estático
Se você estiver usando um quadro para rastrear seu orçamento, essa fórmula pode ser útil. Neste exemplo, o orçamento de viagem para cada funcionário é de $6.500. Queremos determinar se o total gasto em cada funcionário está dentro do orçamento ou o excede. Para fazer isso, compararemos a SOMA() dos valores em quatro colunas com o orçamento usando uma declaração IF().
IF(SUM({Voo},{Hotel},{Seguro},{Despesas})>6500, "Acima do Orçamento","Bom")
Rastreando inventário
Você pode gerenciar facilmente seu inventário com a monday.com. Este exemplo explica como calcular seu estoque disponível atual e quanto do inventário foi vendido (como uma porcentagem).
Para a coluna “Em Estoque”:
MINUS(MINUS({Inventário Inicial},{Reservado}),{Vendido})
Para a coluna “% Vendido”:
ROUND(MULTIPLY(DIVIDE({Vendido},{Inventário Inicial}),100),2)
Formatando uma fórmula
Usando a função TEXT(), você pode formatar seus resultados exatamente da maneira que deseja. Vamos pegar um exemplo simples da primeira linha do quadro a seguir. Queremos multiplicar 100 por 25, e queremos que a saída seja exibida como $2.500,00.
TEXT(MULTIPLY({Inventário Inicial},{Custo}),"$#,##.00")
Na última parte da fórmula, cada # representa um número. Adicionamos .00 ao final porque queremos que a saída termine com dois zeros, mas você pode substituir isso por .## se quiser que sua saída termine com números calculados. O $ coloca o símbolo na frente do número.
Lembre-se de que se você formatar um número usando a função TEXT(), a coluna de fórmula lerá o número como texto em vez de um número. Isso significa que o resumo da sua coluna mostrará “N/A” (como acima) em vez da soma/média/etc dos números mostrados na sua coluna de fórmula.
Resumindo números em uma Coluna Espelho
A Coluna de Fórmula pode ser usada para resumir uma Coluna Espelho, desde que a coluna sendo espelhada seja uma Coluna de Números. Para criar esse resumo, adicione a coluna Fórmula ao seu quadro e use a seguinte função:
SUM({Espelho})
Por exemplo, usaremos uma Coluna Espelho em um quadro de alto nível para exibir o orçamento do projeto. A coluna “Orçamento” é uma Coluna de Números de um quadro relacionado de baixo nível.
A Coluna de Fórmula então puxará os números da Coluna Espelho e gerará um resumo na parte inferior da coluna.
Ainda precisa de assistência? Acesse o suporte da monday.com.
Sabia que a Audatia é parceira oficial da monday.com no Brasil? Ajudamos times a extrair o máximo da ferramenta com consultoria especializada e treinamentos focados na sua operação. Conheça nossos serviços →
